批量（word）删除空行的方法

彩局

方法一：
   对于硬回车：(就是在文本处理的时候，没到换行的时候按回车强制换行，显示的是一个深色的回车键。)

　　＂编辑－－替换＂　－查找内容为＂^p^p＂，替换成＂^p＂然后全部替换！

　　对于软回车：（一般的情况是打字打到右边的边界会自动跳到下一行，上一行的行末有个浅色的回车键，这个是软回车。）

　　＂编辑－－替换＂　－查找内容为＂^l^l＂，替换成＂^l＂然后全部替换！

方法二：
     打开一个空白文档，进入“工具”菜单，选择“宏”，然后选择“宏”。在“宏名”栏中输入“删除空行”需要确保在下拉菜单中的“将宏保存在”选择“所有文档（Normal.dot）”，这将保证你能够在所有Word文档中使用这个宏。如果你不选择这个选项，当你想要打开一个新的Word文档的时候，你就会看到一条屏幕安全信息，你将不能够使用这个宏。 单击“创建”创建以“删除空行”命名的宏，单击该宏，选择“编辑”进入vb编辑框。在框内出入以下程序：

Sub 删除空行()
      Dim MyBar As CommandBarControl
      On Error Resume Next
      Application.CommandBars("Text").Controls("粘贴文本并删除空行").Delete
      Set MyBar = Application.CommandBars("Text").Controls.Add(Before:=4)
      With MyBar
          .Caption = "粘贴文本并删除空行"
          .FaceId = 480
          .OnAction = "PasteAndDel"
      End With
End Sub
'----------------------

Sub PasteAndDel()
      Dim StartRange As Long, EndRange As Long, MyRange As Range, OldEnd As Long
      Dim i As Paragraph
          On Error Resume Next
      '判断剪贴板是否有内容
      If Application.CommandBars.FindControl(ID:=22).Enabled = False Then Exit Sub
      Application.ScreenUpdating = False
      '原文档结束点位置
      OldEnd = ActiveDocument.Content.End
      With Selection
          .Collapse Direction:=wdCollapseEnd      '折叠到选定位置的末端
          StartRange = .Start      '获得一个位置
          .Range.PasteSpecial DataType:=wdPasteText      '光标处选择性粘贴为文本格式
          '获得粘贴后文本的末位置
          EndRange = StartRange + ActiveDocument.Content.End - OldEnd
          ActiveDocument.Range(StartRange, EndRange).Select      '选定该段文本
          For Each i In .Paragraphs      '指定段落中循环
              If Len(i.Range) = 1 Then i.Range.Delete      '如果为空行则删除
          Next
          .Copy      '重新复制,以便调用
      End With
      Application.ScreenUpdating = True
End Sub
单击“保存”对程序进行保存
此时在word空白页右键，在弹出的菜单栏里，可以看到新增了一个命令按钮“粘贴文本并删除空行”，就可以对文本进行操作了。（注：只能对文本进行操作）